Trovare indirizzo I2C di un modulo con Arduino

Nel post di oggi vedremo uno sketch che ci permette di Trovare indirizzo I2C di un modulo con Arduino, utile quando non si conosce o non si riesce a trovare l’indirizzo di un qualsiasi modulo.

Trovare indirizzo I2C di un modulo con Arduino

Sketch I2C Scanner

L’Inter Integrated Circuit (I2C) è un protocollo di comunicazione seriale che utilizza solo due cavi. Solitamente ai moduli viene assegnato, dal costruttore, un indirizzo di comunicazione. Alcuni moduli permettono anche di poter modificare l’indirizzo I2C.
Se il nostro modulo non permette di configurare l’indirizzo, o non si conosce quello assegnato di default, possiamo ricavarlo collegandolo ad una board Arduino e utilizzando lo sketch seguente (trovato su https://playground.arduino/):

 // --------------------------------------
// i2c_scanner
//
// Version 1
//    This program (or code that looks like it)
//    can be found in many places.
//    For example on the Arduino.cc forum.
//    The original author is not know.
// Version 2, Juni 2012, Using Arduino 1.0.1
//     Adapted to be as simple as possible by Arduino.cc user Krodal
// Version 3, Feb 26  2013
//    V3 by louarnold
// Version 4, March 3, 2013, Using Arduino 1.0.3
//    by Arduino.cc user Krodal.
//    Changes by louarnold removed.
//    Scanning addresses changed from 0...127 to 1...119,
//    according to the i2c scanner by Nick Gammon
//    https://www.gammon.com.au/forum/?id=10896
// Version 5, March 28, 2013
//    As version 4, but address scans now to 127.
//    A sensor seems to use address 120.
// Version 6, November 27, 2015.
//    Added waiting for the Leonardo serial communication.
// 
//
// This sketch tests the standard 7-bit addresses
// Devices with higher bit address might not be seen properly.
//

#include <Wire.h>


void setup()
{
  Wire.begin();

  Serial.begin(9600);
  while (!Serial);             // Leonardo: wait for serial monitor
  Serial.println("\nI2C Scanner");
}


void loop()
{
  byte error, address;
  int nDevices;

  Serial.println("Scanning...");

  nDevices = 0;
  for(address = 1; address < 127; address++ ) 
  {
    // The i2c_scanner uses the return value of
    // the Write.endTransmisstion to see if
    // a device did acknowledge to the address.
    Wire.beginTransmission(address);
    error = Wire.endTransmission();

    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.print(address,HEX);
      Serial.println("  !");

      nDevices++;
    }
    else if (error==4) 
    {
      Serial.print("Unknown error at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.println(address,HEX);
    }    
  }
  if (nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");

  delay(5000);           // wait 5 seconds for next scan
}

Lo sketch, una volta collegato il modulo di cui si vuole trovare l’indirizzo I2C, non fa altro che scansionare tutti gli indirizzi possibili fino a quando non trova quello relativo al modulo connesso.

Esempio di utilizzo

Per vedere in pratica come funziona lo sketch ho realizzato un circuito utilizzato i seguenti materiali:

• Arduino Nano ATmega328P CH340G: (Link Amazon – Link eBay)
• Display LCD I2C 0.96 128×64 Pixel SSD1306: (Link Amazon – Link eBay)
• Breadboard: basetta forata sperimentale (Link Amazon – Link eBay)
• Jumper Wire: cavetti elettrici (Link Amazon – Link eBay)
• Arduino IDE: ambiente di sviluppo (per l’installazione e la configurazione vi rimando a questi post)

Effettuiamo i collegamenti tra il modulo I2C (il Display nel mio caso) e il micro-controllore come mostrato nella tabella seguente:

Questo il circuito realizzato con Fritzing

Configurazione IDE e test dello sketch I2C_scanner

Ora colleghiamo la board Arduino al PC, tramite la porta USB, e configuriamola dal pannello Strumenti dell’IDE in questo modo

• Scheda -> Arduino Nano
• Processore -> ATmega328P
• Porta -> COM3 (N.B. la porta potrebbe essere differente)

Da Arduino IDE creiamo un nuovo file, incolliamo lo sketch che abbiamo visto poco prima, e carichiamolo cliccando sul pulsante Carica (contrassegnato da una freccia rivolta verso destra)

Se non ci sono errori e lo sketch viene caricato correttamente, aprendo il Monitor Seriale da Strumenti -> Monitor Seriale vedremo visualizzato l’indirizzo I2C rilevato dal modulo

Per maggiori informazioni sul protocollo I2C vi rimando alla pagina di wikipedia a questo link.

A presto 😉