Inviare comandi ZPL in Dynamics Nav tramite protocollo TCP

^XA

^FX Top section with company logo, name and address.
^CF0,60
^FO50,50^GB100,100,100^FS
^FO75,75^FR^GB100,100,100^FS
^FO88,88^GB50,50,50^FS
^FO220,50^FDInternational Shipping, Inc.^FS
^CF0,40
^FO220,100^FD1000 Shipping Lane^FS
^FO220,135^FDShelbyville TN 38102^FS
^FO220,170^FDUnited States (USA)^FS
^FO50,250^GB700,1,3^FS

^FX Second section with recipient address and permit information.
^CFA,30
^FO50,300^FDJohn Doe^FS
^FO50,340^FD100 Main Street^FS
^FO50,380^FDSpringfield TN 39021^FS
^FO50,420^FDUnited States (USA)^FS
^CFA,15
^FO600,300^GB150,150,3^FS
^FO638,340^FDPermit^FS
^FO638,390^FD123456^FS
^FO50,500^GB700,1,3^FS

^FX Third section with barcode.
^BY5,2,270
^FO100,550^BC^FD12345678^FS

^FX Fourth section (the two boxes on the bottom).
^FO50,900^GB700,250,3^FS
^FO400,900^GB1,250,3^FS
^CF0,40
^FO100,960^FDShipping Ctr. X34B-1^FS
^FO100,1010^FDREF1 F00B47^FS
^FO100,1060^FDREF2 BL4H8^FS
^CF0,190
^FO485,965^FDCA^FS

^XZ

    PROCEDURE PrintZebraZPL@1101318031(IPPar@1101318007 : Text[20];portPar@1101318008 : Integer;zplTextPar@1101318009 : Text);
    VAR
      zplIP@1101318000 : DotNet "'System, Version=4.0.0.0, Culture=neutral, PublicKeyToken=b77a5c561934e089'.System.Net.IPAddress";
      zplIPEndPoint@1101318002 : DotNet "'System, Version=4.0.0.0, Culture=neutral, PublicKeyToken=b77a5c561934e089'.System.Net.IPEndPoint";
      zplPort@1101318001 : Integer;
      socket@1101318003 : DotNet "'System, Version=4.0.0.0, Culture=neutral, PublicKeyToken=b77a5c561934e089'.System.Net.Sockets.Socket";
      socketType@1101318004 : DotNet "'System, Version=4.0.0.0, Culture=neutral, PublicKeyToken=b77a5c561934e089'.System.Net.Sockets.SocketType";
      protocolType@1101318005 : DotNet "'System, Version=4.0.0.0, Culture=neutral, PublicKeyToken=b77a5c561934e089'.System.Net.Sockets.ProtocolType";
      encoding@1101318006 : DotNet "'mscorlib, Version=4.0.0.0, Culture=neutral, PublicKeyToken=b77a5c561934e089'.System.Text.Encoding";
    BEGIN
	
	  //connect to ZPL Printer
      zplIP := zplIP.Parse(IPPar);
      zplPort := portPar;
      zplIPEndPoint := zplIPEndPoint.IPEndPoint(zplIP, zplPort);
      socket := socket.Socket(zplIP.AddressFamily, socketType.Stream, protocolType.Tcp);
      socket.Connect(zplIPEndPoint);
      IF socket.Connected THEN BEGIN
        //send ZPL commands
        encoding := encoding.ASCII;
        socket.Send(encoding.GetBytes(zplTextPar));
        socket.Close;
      END;
    END;